2011/06/03 02:14:58
our宣言とvarsプラグマは等価じゃないです。 #Perl

確かに等価ではありませんので、その違いを詳しく考えてみたいと思います。

まず、ourはレキシカルスコープを持ちますが、varsプラグマにはそれがありません。

ourの場合、スコープを抜けての使用はエラーになります。

use strict;
use warnings;
{
    our $foo = "foo";
}
warn $foo; # Global symbol "$foo" requires explicit package name

varsプラグマの場合はuse vars以後であれば、レキシカルスコープはもちろん、ファイルスコープを超えても使用が許されます。スコープが無いのでno varsのような使い方はできません。

use strict;
use warnings;
{
    use vars qw($foo);
    $foo = "foo";
}
require 'foo.pl'; # $fooを使用している
warn $foo; # foo

また、名前の決定にはレキシカルスコープが優先されるため、同名のレキシカル変数が存在するスコープにおいてvarsプラグラマは意味を持ちません。（そのスコープを超えて初めて効果を発揮します。）

次のようにourは正しくスコープ内で認識されます。

use strict;
use warnings;
my $foo="bar";
{
    our $foo = "foo";
}
warn $foo; # "bar"

以下は同名のmy変数が存在するため、上書きに参照されるのはvarsプラグマで宣言したグローバル変数にはなりません。

use strict;
use warnings;
my $foo="bar";
{
    use vars qw($foo);
    $foo = "foo"; # my変数を上書き
}
warn $foo; # "foo"

vars.pmの中身は、宣言した変数をその場で名前空間に輸入する単純なコードです。

ourの場合はmy変数と同様に字句解析されます。その残骸が次のようなコードでも確認できます。

$ perl -MO=Showlex -Mstrict -Mvars=\$z -e 'my $x; our $y; $z;'
Pad of lexical names for comppadlist has 3 entries
0: SPECIAL #1 &PL_sv_undef
1: PVNV (0x100827dc8) $x
2: PVMG (0x100827df8) $y
... 

ourで宣言された変数$yはスクラッチパッド上に存在しないものの、そのシンボルテーブルには名前が残っています。

strict varsプラグラマが効いていると、修飾されない名前でのグローバル変数へのアクセスが禁止されます。ourやvarsプラグマは、それを解除するための方法とも考えられます。

それが全く異なるやり方で実装されているため、上記のように違いが表に出る事もあるようです。

ただ、通常は問題になりませんね（笑）